DAX til copy-paste¶

Alle målene fra kurset, klar til at indsætte direkte i Power BI's formelboks. Højreklik på Salg-tabellen → Nyt mål og indsæt én blok ad gangen.

Grundmål¶

Antal Ordrer

Antal Ordrer = COUNTROWS( Salg )

Total Omsætning

Total Omsætning =
SUMX(
    Salg,
    Salg[Antal] * Salg[EnhedsPris] * ( 1 - Salg[Rabat] )
)

Månedsbudget (pr. kategori)

Månedsbudget = SUM( Produkter[MaanedsBudget] )

Modul 4 - CALCULATE¶

Ordrer Salg

Ordrer Salg =
CALCULATE(
    COUNTROWS( Salg ),
    Salg[Afdeling] = "Salg"
)

Ordrer Total - på tværs af afdelinger

Ordrer Total =
CALCULATE(
    COUNTROWS( Salg ),
    ALL( Salg[Afdeling] )
)

Ordrer Audio

Ordrer Audio =
CALCULATE(
    COUNTROWS( Salg ),
    Produkter[Kategori] = "Audio"
)

Modul 5 - SUMX¶

Bruttoavance

Bruttoavance =
SUMX(
    Salg,
    Salg[Antal] * Salg[EnhedsPris] * ( 0.4 - Salg[Rabat] )
)

Beregnede kolonner, ikke mål

De to næste tilføjes via Ny kolonne på Salg-tabellen.

Kategori

Kategori = RELATED( Produkter[Kategori] )

Produktbeskrivelse

Produktbeskrivelse =
RELATED( Produkter[Produktnavn] ) & " (" & RELATED( Produkter[Kategori] ) & ")"

Listepris-Omsætning (mål)

Listepris-Omsætning =
SUMX(
    Salg,
    Salg[Antal] * RELATED( Produkter[Listepris] )
)

Modul 7 - FILTER¶

Store Handler

Store Handler =
CALCULATE(
    COUNTROWS( Salg ),
    FILTER(
        Salg,
        Salg[Antal] * Salg[EnhedsPris] * ( 1 - Salg[Rabat] ) > 10000
    )
)

Omsætning Store Handler

Omsætning Store Handler =
VAR StorTærskel = 10000
RETURN
SUMX(
    FILTER(
        Salg,
        Salg[Antal] * Salg[EnhedsPris] * ( 1 - Salg[Rabat] ) > StorTærskel
    ),
    Salg[Antal] * Salg[EnhedsPris] * ( 1 - Salg[Rabat] )
)

Store Rabat-handler

Store Rabat-handler =
CALCULATE(
    COUNTROWS( Salg ),
    FILTER(
        Salg,
        Salg[Rabat] > 0.15
            && Salg[Antal] * Salg[EnhedsPris] > 5000
    )
)

Modul 8 - IF¶

Budget Status

Budget Status =
IF(
    [Total Omsætning] >= [Månedsbudget],
    "Over",
    "Under"
)

Budget Status 3 (tre niveauer - SWITCH-version)

Budget Status 3 =
SWITCH(
    TRUE(),
    [Total Omsætning] >= [Månedsbudget] * 1.10, "Stærkt over",
    [Total Omsætning] >= [Månedsbudget] * 0.90, "På sporet",
    "Under"
)

Status Farve (til betinget formatering)

Status Farve =
IF( [Total Omsætning] >= [Månedsbudget], "#2E7D32", "#C62828" )

Handelsstørrelse (beregnet kolonne på Salg)

Handelsstørrelse =
VAR LinjeOms = Salg[Antal] * Salg[EnhedsPris] * ( 1 - Salg[Rabat] )
RETURN
SWITCH(
    TRUE(),
    LinjeOms > 10000, "Stor",
    LinjeOms >= 2000, "Mellem",
    "Lille"
)

Modul 9 - Samlet vækststatus¶

Forudsætter kalendertabel

Hvis du ikke har en endnu, indsæt under Modellering → Ny tabel:

Kalender = CALENDAR( DATE(2025, 1, 1), DATE(2026, 12, 31) )

Markér som datotabel, og lav relation til Salg[Dato].

Omsætning Store Handler SidsteÅr

Omsætning Store Handler SidsteÅr =
CALCULATE(
    [Omsætning Store Handler],
    SAMEPERIODLASTYEAR( Kalender[Dato] )
)

Vækststatus (det store finalemål)

Vækststatus =
VAR Nu = [Omsætning Store Handler]
VAR Før = [Omsætning Store Handler SidsteÅr]
VAR Vækst = Nu - Før
VAR VækstProcent = DIVIDE( Vækst, Før, 0 )
RETURN
SWITCH(
    TRUE(),
    ISBLANK( Før ), "Ingen sammenligning",
    VækstProcent >= 0.05, "Vækst",
    VækstProcent >= -0.05, "Stabilt",
    "Tilbagegang"
)

Anbefalede formateringer¶

Mål	Format
`Total Omsætning`, `Bruttoavance`, `Omsætning Store Handler`, `Listepris-Omsætning`	Valuta DKK, 0 decimaler
`Månedsbudget`	Valuta DKK, 0 decimaler
`Antal Ordrer`, `Ordrer Salg`, `Ordrer Audio`, `Ordrer Total`, `Store Handler`, `Store Rabat-handler`	Heltal
`Budget Status`, `Budget Status 3`, `Vækststatus`, `Status Farve`	Tekst

Tilbage til snydearket Forside